// ObjOutIn.txt  - Svengali July 08 - revised marcus_civis December 2018
// load and save Object File = 1.obj
// Groups disabled on save


[IConfig, 2021]
[IShowActions, 0]

[VarDef, Object1, "" ]

[RoutineDef,SetPath,
	[If,[FileExists,[FileNameResolvePath,"ZPUBLIC_Temp/OBJpath.zvr"]],
		[VarLoad,Object1,[FileNameResolvePath,"ZPUBLIC_Temp/OBJpath.zvr"]]
		,//else
		[If,md,
			[VarSet, Object1,[FileNameAsk,"OBJ(*.obj)|*.OBJ||","Model.obj","Please Save File..."]]
			,
			[VarSet, Object1,[FileNameAsk,"OBJ(*.obj)|*.OBJ||",,"Please Open File..."]]
		]
		[If,[StrLength,Object1],
			[VarSave,Object1,[FileNameResolvePath,"ZPUBLIC_Temp/OBJpath.zvr"]]
			,//else exit if no file name
			[Exit]			
		]
	]
,md]

[IButton,"TOOL:OBJ out","Export model as obj",
	[RoutineCall,SetPath,1]
	[If, [IGet, TRANSFORM:Edit] == 1,
		[ISet, Preferences:ImportExport:Grp, 0 ]
		[FileNameSetNext, Object1 ]
		[If,[IsEnabled,TOOL:Export],
			[IKeyPress, 13, [IPress,TOOL:Export] ]
			[Note, "Model Saved as OBJ...", , 2 ]
		]
	, // else
		[Note, "No model in edit mode...", , 2 ]
	]
,,0.34]

[IButton,"TOOL:OBJ in","Import model obj",
	[RoutineCall,SetPath,0]
	[If, [FileExists, Object1 ] == 1,
		[FileNameSetNext, Object1 ]
		[IKeyPress, 13, [IPress, TOOL:Import] ]
		[Note, "model OBJ has been loaded...", , 2 ]
	, // else
		[Note, "Sorry, OBJ does not exist...", , 2 ]
	]

,,0.33]

[IButton,"TOOL:Reset","Reset OBJ path",
	[If,[FileExists,"ZPUBLIC_Temp/OBJpath.zvr"],
		[FileDelete,"ZPUBLIC_Temp/OBJpath.zvr"]
	]
	[Note,"OBJ path reset",,2]	
,,0.33]
